在MAXQ8913微控制器中從RAM執行應用程序

MAXQ8913及其它MAXQ?微控制器采用的Harvard存儲器映射架構為用戶提供了極大的靈活性，可根據需要將不同的物理內存(例如數據SRAM)映射為程序或數據內存空間。在特定環境下，從數據SRAM執行一個程序的部分代碼能夠提升性能并降低功耗。這些優勢都是以應用程序的更加復雜為代價。

概述

MAXQ8913和其它許多MAXQ微控制器一樣，也包含了一個基于SRAM的內置數據存儲區域，該存儲區域可被映射為數據內存空間，或者選擇映射為程序內存空間。內置SRAM通常用作數據存儲器，而在程序閃存或掩膜ROM中執行大部分程序代碼。然而，在特定環境下，從內部SRAM執行有限的部分代碼非常有用。

本應用筆記介紹如何配置、裝載匯編程序，以便從內部SRAM正確運行，本文還討論了這種方法的優勢和缺點。本應用筆記給出的例程針對MAXQ8913編寫，使用基于匯編的MAX-IDE環境。用戶可下載本文所涉及的應用程序代碼和項目文件。

本文討論的代碼都特別針對MAXQ8913微控制器編寫，所介紹的原理和方法也同樣適合其它含有可映射為程序空間的內部SRAM的MAXQ微控制器。能夠以這種方式執行代碼的其它MAXQ微控制器包括：MAXQ2000、MAXQ2010和MAXQ3210/MAXQ3212。

該代碼能很好地運行在任何基于MAXQ8913并為MAXQ8913的串口0提供一路串行接口(RS-232或USB至串口轉換)的硬件。將一個終端模擬器連接到該串口，并設置為9600波特率、8個數據位、1個停止位、無奇偶校驗，即可查看例程的代碼輸出。

用戶可免費下載MAX-IDE環境的最新安裝程序包和文檔資料。

• MAX-IDE安裝程序
• MAXQ核編譯指南
• 開發工具指南

在RAM中執行代碼的優勢

通常情況下，MAXQ微控制器的絕大多數應用代碼都被設計為在主程序空間執行，主程序空間通常是利用一片大的內部閃存或(對于掩膜ROM器件)用戶指定的應用ROM來實現。主程序空間為非易失存儲器，所以大多數情況下可用來保存應用程序代碼。內部SRAM被用來存儲變量、軟件棧，以及器件被關閉時不需要保存的類似數據。

然而，對于特定應用，在數據SRAM中執行某些代碼具有一定優勢。

降低功耗

在大多數MAXQ微控制器中，當在內部SRAM (或固定用途ROM)中執行代碼時，相對于程序閃存而言，電源電流會減小。因為閃存在不被存取時可被動態斷電，所以這種情況下就能節省功率。如果某個應用程序通常在大部分活動時間內執行非常小的代碼量，在SRAM中執行就能大大降低總體功耗。

直接訪問主程序空間存儲器

通常，從主程序閃存執行的代碼不能直接讀取保存在主程序閃存中的數據。這種類型的數據可以包括隨應用程序數據一起的常量字符串和數據表。若要讀取該數據，應用程序必須調用固定用途ROM中的專用數據傳遞函數。在RAM中執行代碼則避開了這一限制，允許利用標準的數據指針直接讀取閃存中包含的數據。這就加快了存取操作。若一個小的算法花費大量的時間遍歷閃存中存儲的查找表或其它常量數據，那么在RAM中執行該算法則能夠在非常短的時間內完成運算。

可重寫整個閃存

和大多數基于閃存的MAXQ微控制器一樣，MAXQ8913中的固定用途ROM含有在應用程序控制下擦除和重寫程序閃存的標準函數。該過程能夠使用戶裝載器通過用戶指定接口(例如串口、SPI或I2C)重新裝載部分或全部應用程序。然而，若用戶裝載程序位于閃存內，則不能擦除或重寫自身所占用的閃存。在RAM中執行用戶裝載器，可以擦除整個閃存程序空間并重新寫入新的代碼，包括用戶裝載器本身。

在RAM中執行代碼的缺點

在RAM中執行應用程序代碼也存在缺點和限制。有些缺點與具體工作相關，而有些缺點則是MAXQ架構所固有的。

有限的代碼空間

RAM一般比程序閃存小得多，這意味著在任何給定時間只能執行少量代碼。但有可能在RAM中運行一個例程，然后將其擦除并裝載第二個例程，隨后再運行第二個例程，依此類推。

代碼映射

在RAM中執行代碼之前，必須將其復制到RAM。這一過程需要時間和代碼空間。此外，代碼必須從某個位置復制，所以代碼實際上被存儲兩次：一次在閃存或程序ROM，一次在RAM。即使該代碼不是為了在閃存中執行，也必須被存儲于其中，從而消耗了額外的空間。

不可直接存取RAM

當在RAM中執行代碼時，RAM就不再是可見的數據存儲空間。這意味著不能利用數據指針直接從RAM存儲單元讀取或寫入數據。按照在閃存中運行應用代碼相同的方式，有可能避開這種限制。利用固定用途ROM數據傳遞函數(UROM_moveDP0和類似的函數)可對RAM進行讀取，以及通過在閃存中寫入類似的函數，可直接對RAM進行寫操作。然而，這種迂回方法也占用額外的時間和應用程序空間。

編譯在RAM中執行的代碼

在編寫將要在數據RAM中執行的應用代碼時，必須要考慮一項主要因素。代碼的每個字都將被編譯至一個地址并被裝載至該地址的閃存中，但是將在不同地址的RAM中執行。例如，如果一段代碼被裝載至以程序字地址0100h開始的閃存中，并被復制到以數據字地址0100h開始的RAM中，在RAM中就不可能跳至地址0100h來執行代碼。在閃存中，地址0100h仍然是代碼的地址。在程序空間中，RAM中代碼的地址是其數據存儲地址加上偏移量A000h，如圖1所示。


圖1. MAXQ8913在RAM中執行代碼時的內存映射

為了執行復制到RAM中數據內存地址為0100h的應用程序，必須跳至程序地址A100h。

在RAM中執行代碼會為MAX-IDE編譯器造成困難。MAX-IDE并不知道將在與編譯地址不同的地址執行代碼。例如，假設一個例程調用了閃存地址為0080h的subOne，而另一個位于0300h的例程調用了第一個例程。其代碼如下所示。

org 0080h

subOne:
   ....perform various calculations...
   ret

...

org 0300h

subTw
   call  subOne
   ...and so on...
   

如果兩個例程均被復制到RAM并在此執行，將會發生什么? 假設例程均被復制到RAM中與其在閃存中占用的程序地址相同的數據內存地址，那么subOne將位于程序地址A080h，subTwo將位于A300h。

因為“call subOne”所在行與目標端標簽subOne之間的距離超過了相對跳轉距離(+127/-128個字)，所以指令就必須被重新編譯為絕對LCALL。然而，編譯器所持有的subOne的唯一地址是0080h，所以指令將被編譯為“LCALL 0080h”。當subTwo執行時，它將不調用位于RAM中的subOne副本，而是調用位于閃存中的版本。

有兩種迂回方法可能解決這種困境。第一種方法也是最簡單的方法，即強制編譯器始終使用相對跳轉和調用，并使例程在RAM中離得足夠近，使其能夠按照這一方式調用其它例程。總是使用SJUMP和SCALL，而不是JUMP和CALL機器碼(使編譯器可選擇短或長跳轉)。這將強制使用指令的相對跳轉版本。

然而，這種方法也存在限制。如果在RAM中運行的代碼量長于128個字，相對跳轉就有可能不足以長到使RAM中的一個例程調用另一個例程。這種情況下的解決方法是通過ORG聲明為不同的例程使用固定的地址，然后定義包含其在RAM中的正確地址的等價變量。這些等價變量可被用于LCALL和LJUMP聲明中，如下所示。

subOne  equ  0A080h

org 0080h

; subOne
   ....perform various calculations...
   ret

...

org 0300h

subTw
   lcall  #subOne
   ...and so on...

這一過程強制編譯器為LCALL使用正確的地址。

將代碼復制至RAM

在RAM中執行代碼之前，必須首先將其復制到RAM。將大量代碼從閃存復制到RAM的最簡單方式是使用應用ROM copyBuffer函數。該函數的輸入參數為兩個數據指針(DP[0]和BP[Offs])和一個長度值(LC[0])。它將指定數量的字節/字從源地址DP[0]復制到目標地址BP[Offs]；一次可復制最多256個字節/字。

我們的示例應用程序將其開始的512個字從閃存復制到RAM，然后跳轉至RAM中的副本開始執行代碼。源指針(DP[0])指向程序閃存在應用ROM的內存映射中的地址，從8000h開始。請主意，為了避免無限循環，在復制RAM的代碼之后，我們跳轉至RAM中副本的部分。

org 0020h                    

copyToRAM:
   move    DPC,   #1Ch       ; Ensure all pointers are operating in word mode.
   move    DP[0], #8000h     ; Start of program flash from UROM's perspective.
   move    BP,    #0         ; Start of data memory.
   move    Offs,  #0         
   move    LC[0], #256       ; The Offs register limits us to a 256-word copy.
   lcall   UROM_copyBuffer

   move    DP[0], #8100h     ; Copy second half.
   move    BP,    #0100h
   move    Offs,  #0
   move    LC[0], #256
   lcall   UROM_copyBuffer

   ljump   #0A040h           ; Begin execution of code from RAM.


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;  Executing from RAM
;;

org 0040h

   move    LC[0], #1000
delayLoop:
   move    LC[1], #8000
   sdjnz   LC[1], $
   sdjnz   LC[0], delayLoop

;; Initialize serial port.

   move    SCON.6, #1        ; Set to mode 1 (10-bit asynchronous).
   move    SMD.1,  #1        ; Baud rate = 16 x baud clock
   move    PR, #009D4h       ; P = 2^21 * 9600/8.000MHz
   move    SCON.1, #0        ; Clear transmit character flag.

數據傳遞操作

如上所述，在RAM中執行代碼時，有兩個與內存映射相關的事項發生了變化。第一，程序閃存現在被映射至數據內存。這意味著我們可通過任意數據指針直接從程序閃存讀取數據，如下所示。

;; Read the banner string from flash and output it over the serial port.  Since
;; we are running from RAM, we can read from the flash directly without having
;; to use the Utility ROM data transfer functions (moveDP0inc, etc...).

   move    SC.4,  #0
   move    DPC,   #0                  ; Set pointers to byte mode.
   move    DP[0], #(stringData * 2)   ; Point to byte address of string data.

stringLoop:
   move    Acc, @DP[0]++
   sjump   Z, stringEnd
   lcall   #TxChar
   sjump   stringLoop
stringEnd:
   move    DPC, #1Ch         ; Set pointers to word mode.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;  This portion of the code (addresses 200h and higher) will remain in flash.

org 0200h

stringData:
   db      0Dh, 0Ah, "Executing code from RAM....", 00h

請注意，如圖1所示，SC.4 (CDA0)位影響將哪一半程序閃存(上半頁或下半頁)以字節模式映射至數據內存。當使用字模式指針時，整個程序閃存被一次性映射至數據內存。

第二，現在雖然閃存在數據空間可存取，但SRAM不可直接存取。這意味著不能對SRAM的存儲單元進行讀或寫操作，應用程序必須采取迂回的方法。從SRAM存儲單元讀取數據可按照在閃存中運行的代碼從閃存存儲單元讀取數據相同的方式實現—利用應用ROM數據傳遞函數(moveDP0inc等)。然而，由于在應用ROM中沒有類似的函數可實現直接寫操作，所以應用程序必須提供一個小函數駐留在閃存中，該函數可被RAM中駐留的代碼直接調用來執行寫操作。

以下的代碼演示用來讀和寫RAM變量varA的方法，其初始值隨其它部分的應用程序被從閃存復制到RAM，地址范圍為0000h-01FFh。

   scall   printVar
   scall   incrVar
   scall   printVar
   scall   incrVar
   scall   printVar
   scall   incrVar

   move    Acc, #0Dh
   lcall   #TxChar
   move    Acc, #0Ah
   lcall   #TxChar
   
   sjump   $


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;  Variables stored in RAM (program) space.  They can be read using the 
;;  Utility ROM data transfer functions (such as UROM_moveDP0) and written 
;;  using the writeDP0 function which remains in flash.
;;

varA:
   dw 'A'


;================================================================
;=
;=  printVar
;=
;=  Reads the varA RAM variable value and sends it over the serial port.
;=

printVar:
   move    DPC, #1Ch         ; Word mode
   move    DP[0], #varA      ; Variable's location in UROM data space
   lcall   UROM_moveDP0      ; Moves variable value into GR.
   move    Acc, GR
   lcall   #TxChar
   ret


;==============================================================
;=
;=  incrVar
;=
;=  Reads the varA RAM variable value, adds 1 to it, and stores it back in RAM.
;=

incrVar:
   move    DPC, #1Ch         ; Word mode
   move    DP[0], #varA      ; Variable's location in UROM data space
   lcall   UROM_moveDP0      ; Moves variable value into GR.

   move    Acc, GR
   add     #1
   move    GR, Acc
   lcall   writeDP0

   ret



;==================================================================
;=
;=  TxChar
;=
;=  Outputs a character to the serial port.
;=
;=  Inputs  : Acc.L - Character to send.
;=

org 01F0h
   move    SBUF, Acc         ; Send character.
TxChar_Loop:
   move    C, SCON.1         ; Check transmit flag.
   sjump   NC, TxChar_Loop   ; Stall until last transmit has completed.
   move    SCON.1, #0        ; Clear the transmit flag.
   ret


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;  This portion of the code (addresses 200h and higher) will remain in flash.

org 0200h

stringData:
   db      0Dh, 0Ah, "Executing code from RAM....", 00h


;===============================================================
;=
;=  WriteRAM
;=
;=  This is a routine that can be called by code running in the RAM to load
;=  a new value into a byte or word location in the RAM.
;=
;=  Inputs  : DP[0] - Location to write (absolute starting at 0000h) in RAM.
;=            GR    - Value to write to the RAM location.
;=  
;=  Notes   : DP[0] must be configured to operate in word or byte mode as
;=            desired before calling this function.  Following a call to this
;=            function, DP[0] must be refreshed before it is used to read data.
;=            

writeDP0:
   move    @DP[0], GR
   ret

在執行時，示例代碼通過串口輸出以下的文字(圖2)。


圖2. 示例代碼通過串口的輸出文字

結論

利用MAXQ8913及其它MAXQ微控制器采用的Harvard內存映射架構，可以將不同的物理內存段(例如數據SRAM)映射為程序或數據內存空間。在數據SRAM中執行部分應用程序為性能提升和降低功耗提供了潛力。不過該過程也增加了應用程序的復雜性。