本章教程主要跟大家講STM32H7的啟動過程，這里的啟動過程是指從CPU上電復位執行第1條指令開始（匯編文件）到進入C程序main()函數入口之間的部分。

啟動過程相對來說還是比較重要的，理解了這個過程，對于以后分析程序還是有些幫助的，要不每次看到這個啟動過程都會跳過，直接去看主程序了。

還有就是以后打算學習RTOS的話，對于這個過程必須有個了解，因為移植的時候涉及到中斷向量表。

對初學者來說，看這個可能有些吃力，不過不要緊，隨著自己做過一些簡單的應用之后再來看這章，應該會有很多的幫助，由于我們的V7板子是基于STM32H7XXX，所以我們這里主要針對H7系列的啟動過程做一下分析，對于F1，F4系列也是大致相同的。

1 初學者重要提示

相比F1，F4的啟動方式，H7的啟動方式更靈活些，只需一個boot引腳即可。但是一個引腳只能區分出兩個狀態，為了解決這個問題，H7專門配套了兩個option bytes選項字節來解決此問題。

2 各個版本的啟動文件介紹

這里各個版本的意思是指不同的編譯器、不同的H7系列對應的啟動文件。

2.1 不同編譯器對應的啟動文件

打開我們為本教程提供的工程文件，路徑如下：

LibrariesCMSISDeviceSTSTM32H7xxSourceTemplates 在這個文件里面有ST官方為各個編譯器提供的啟動文件。

看了上面的截圖，大家會問怎么沒有KEIL MDK呢？其實已經被放在了文件夾arm里面，KEIL公司已經在2005年被ARM公司收購了。開發板大部分例程都是配套了MDK和IAR兩個版本，這里重點給大家分析一下MDK的啟動文件分析，IAR和MDK的大同小異。

2.2 不同H7系列對應的啟動文件

先來看一下ARM文件夾里面的文件（2018-07-03，當前只有如下兩個系列，后期ST會增加新的型號，相應的啟動文件也會添加進來）：

如果是H743系列，就使用startup_stm32h743xx.s文件，如果是H753系列，就使用startup_stm32h753xx文件。當前H743和753系列對應的型號如下：

我們再來打開IAR文件夾里面的文件：

多了一個linker文件夾，用于IAR配置的ICF文件：

而啟動文件跟MDK里面的一樣，一個是用H743系列，另一個是用于H753系列。

3 啟動文件分析

鑒于V7開發板使用的是STM32H743XI，下面我們詳細的分析一下啟動文件startup_stm32h743xx.s。分析前，先掌握一個小技能，遇到不認識的指令或者關鍵詞可以檢索。

啟動 MDK軟件，在Help菜單點擊 uVision Help

點擊后彈出如下文件

在搜索欄輸入你需要查詢的單詞進行查詢，然后點擊“列出主題”按鈕，會將相關的知識點都羅列出來。此功能非常實用，建議熟練掌握。

下面先來看啟動文件前面的介紹 （固件庫版本：V1.2.0）

;******************** (C) COPYRIGHT 2017 STMicroelectronics ********************
;* File Name          : startup_stm32h743xx.s
;* @author  MCD Application Team
;* version            : V1.2.0
;* Date               : 29-December-2017
;* Description        : STM32H7xx devices vector table for MDK-ARM toolchain. 
;*                      This module performs:
;*                      - Set the initial SP
;*                      - Set the initial PC == Reset_Handler
;*                      - Set the vector table entries with the exceptions ISR address
;*                      - Branches to __main in the C library (which eventually
;*                        calls main()).
;*                      After Reset the Cortex-M processor is in Thread mode,
;*                      priority is Privileged, and the Stack is set to Main.
;* <<< Use Configuration Wizard in Context Menu >>>   
;*******************************************************************************
; 
; Licensed under MCD-ST Liberty SW License Agreement V2, (the "License");
; You may not use this file except in compliance with the License.
; You may obtain a copy of the License at:
; 
;        http://www.st.com/software_license_agreement_liberty_v2
; 
; Unless required by applicable law or agreed to in writing, software 
; distributed under the License is distributed on an "AS IS" BASIS, 
; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
; See the License for the specific language governing permissions and
; limitations under the License.
; 
;*******************************************************************************

啟動文件是后綴為.s的匯編語言文本文件，每行前面的分號表示此行是注釋行。

啟動文件主要完成如下工作，即程序執行過程：

- 設置堆棧指針SP = __initial_sp。

- 設置PC指針 = Reset_Handler。

- 設置中斷向量表。

- 配置系統時鐘。

- 配置外部SRAM/SDRAM用于程序變量等數據存儲（這是可選的）。

- 跳轉到C庫中的 __main ，最終會調用用戶程序的main()函數。

Cortex-M內核處理器復位后，處于線程模式，指令權限是特權級別（最高級別），堆棧設置為使用主堆棧MSP。

3.1 復位序列

硬件復位之后，CPU 內的時序邏輯電路首先完成如下兩個工作（程序代碼下載到內部flash為例，flash首地址0x0800 0000）

將0x08000000位置存放的堆棧棧頂地址存放到SP中(MSP)。

將0x08000004 位置存放的向量地址裝入 PC 程序計數器。

CPU 從 PC 寄存器指向的物理地址取出第 1 條指令開始執行程序，也就是開始執行復位中斷服務程序 Reset_Handler。

復位中斷服務程序會調用SystemInit()函數來配置系統時鐘、配置FMC總線上的外部SRAM/SDRAM，然后跳轉到C 庫中__main 函數。由C庫中的__main 函數完成用戶程序的初始化工作（比如：變量賦初值等），最后由__main 函數調用用戶寫的 main()函數開始執行 C 程序。

13.3.2 代碼分析

第1部分代碼分析

下面的代碼實現開辟棧(stack)空間，用于局部變量、函數調用、函數的參數等。

; Amount of memory (in bytes) allocated for Stack
; Tailor this value to your application needs
;  Stack Configuration
;    Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
; 
  
Stack_Size      EQU     0x00000400


                AREA    STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem       SPACE   Stack_Size
__initial_sp

第7行：EQU 是表示宏定義的偽指令，類似于 C 語言中的#define。偽指令的意思是指這個“指令”并不會生成二進制程序代碼，也不會引起變量空間分配。

0x00000400 表示棧大小，注意這里是以字節為單位。

第9行：開辟一段數據空間可讀可寫，段名 STACK，按照 8 字節對齊。ARER 偽指令表示下面將開始定義一個代碼段或者數據段。此處是定義數據段。ARER 后面的關鍵字表示這個段的屬性。

STACK ：表示這個段的名字，可以任意命名。

NOINIT：表示此數據段不需要填入初始數據。

READWRITE：表示此段可讀可寫。

ALIGN=3 ：表示首地址按照 2 的 3 次方對齊，也就是按照 8 字節對齊(地址對8求余數等于0)。

第10行：SPACE 這行指令告訴匯編器給 STACK 段分配 0x00000400 字節的連續內存空間。

第11行： __initial_sp 緊接著 SPACE 語句放置，表示了棧頂地址。__initial_sp 只是一個標號，標號主要用于表示一片內存空間的某個位置，等價于 C 語言中的“地址”概念。地址僅僅表示存儲空間的一個位置，從 C 語言的角度來看，變量的地址，數組的地址或是函數的入口地址在本質上并無區別。

第2部分代碼分析

下面的代碼實現開辟堆(heap)空間，主要用于動態內存分配，也就是說用 malloc，calloc, realloc等函數分配的變量空間是在堆上。

1.    ;  Heap Configuration
2.    ;     Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
3.    ; 
4.    
5.    Heap_Size       EQU     0x00000200
6.    
7.                    AREA    HEAP, NOINIT, READWRITE, ALIGN=3
8.    __heap_base
9.    Heap_Mem        SPACE   Heap_Size
10.    __heap_limit

這幾行語句和上面第1部分代碼類似。分配一片連續的內存空間給名字叫 HEAP 的段，也就是分配堆空間。堆的大小為 0x00000200。

__heap_base 表示堆的開始地址。

__heap_limit 表示堆的結束地址。

第3部分代碼分析

1.                    PRESERVE8
2.                    THUMB
3.    
4.    
5.    ; Vector Table Mapped to Address 0 at Reset
6.                    AREA    RESET, DATA, READONLY
7.                    EXPORT  __Vectors
8.                    EXPORT  __Vectors_End
9.                    EXPORT  __Vectors_Size

第1行：PRESERVE8 指定當前文件保持堆棧八字節對齊。

第2行：THUMB表示后面的指令是THUMB指令集 ，CM7采用的是THUMB - 2指令集。

第6行：AREA定義一塊代碼段，只讀，段名字是 RESET。READONLY 表示只讀，缺省就表示代碼段了。

第7-9行：3 行EXPORT語句將 3 個標號申明為可被外部引用， 主要提供給鏈接器用于連接庫文件或其他文件。

第4部分代碼分析

1.    __Vectors       DCD     __initial_sp                      ; Top of Stack
2.                    DCD     Reset_Handler                     ; Reset Handler
3.                    DCD     NMI_Handler                       ; NMI Handler
4.                    DCD     HardFault_Handler                 ; Hard Fault Handler
5.                    
6.                    中間部分省略未寫
7.    
8.                    DCD     0                                 ; Reserved                                    
9.                    DCD     WAKEUP_PIN_IRQHandler             ; Interrupt for all 6 wake-up pins 
10.                    
11.    
12.    __Vectors_End
13.    
14.    __Vectors_Size  EQU  __Vectors_End - __Vectors

上面的這段代碼是建立中斷向量表，中斷向量表定位在代碼段的最前面。具體的物理地址由鏈接器的配置參數（IROM1 的地址）決定。如果程序在 Flash 運行，則中斷向量表的起始地址是 0x08000000。

以MDK為例，就是如下配置選項：

DCD表示分配 1 個 4 字節的空間。每行 DCD 都會生成一個 4 字節的二進制代碼。中斷向量表存放的實際上是中斷服務程序的入口地址。當異常（也即是中斷事件）發生時，CPU 的中斷系統會將相應的入口地址賦值給 PC 程序計數器，之后就開始執行中斷服務程序。

第5部分代碼分析

1.                    AREA    |.text|, CODE, READONLY
2.    
3.    ; Reset handler
4.    Reset_Handler    PROC
5.                     EXPORT  Reset_Handler                    [WEAK]
6.            IMPORT  SystemInit
7.            IMPORT  __main
8.    
9.                     LDR     R0, =SystemInit
10.                     BLX     R0
11.                     LDR     R0, =__main
12.                     BX      R0
13.                     ENDP

第1行：AREA 定義一塊代碼段，只讀，段名字是 .text 。READONLY 表示只讀。

第4行：利用 PROC、ENDP 這一對偽指令把程序段分為若干個過程，使程序的結構加清晰。

第5行：WEAK 聲明其他的同名標號優先于該標號被引用,就是說如果外面聲明了的話會調用外面的。 這個聲明很重要，它讓我們可以在C文件中任意地方放置中斷服務程序，只要保證C函數的名字和向量表中的名字一致即可。

第6行：IMPORT：偽指令用于通知編譯器要使用的標號在其他的源文件中定義。但要在當前源文件中引用，而且無論當前源文件是否引用該標號，該標號均會被加入到當前源文件的符號表中。

第9行：SystemInit 函數在文件system_stm32h7xx.c 里面，主要實現RCC相關寄存器復位和中斷向量表位置設置。

第11行：__main 標號表示C/C++標準實時庫函數里的一個初始化子程序__main 的入口地址。該程序的一個主要作用是初始化堆棧(跳轉__user_initial_stackheap 標號進行初始化堆棧的，下面會講到這個標號)，并初始化映像文件，最后跳轉到 C 程序中的 main函數。這就解釋了為何所有的 C 程序必須有一個 main 函數作為程序的起點。因為這是由 C/C++標準實時庫所規，并且不能更改。

第6部分代碼分析

代碼如下：

1.    ; Dummy Exception Handlers (infinite loops which can be modified)
2.    
3.    NMI_Handler     PROC
4.                    EXPORT  NMI_Handler                      [WEAK]
5.                    B       .  
6.                    ENDP
7.    HardFault_Handler
8.                    PROC
9.                    EXPORT  HardFault_Handler                [WEAK]
10.                    B       .
11.                    ENDP
12.    
13.                    中間部分省略未寫
14.    Default_Handler PROC                                      
15.    
16.                    EXPORT  WWDG_IRQHandler                   [WEAK]                                       
17.                    EXPORT  PVD_AVD_IRQHandler                [WEAK]                         
18.                    EXPORT  TAMP_STAMP_IRQHandler             [WEAK]
19.                    中間部分省略未寫
20.    SAI4_IRQHandler      
21.    WAKEUP_PIN_IRQHandler
22.    
23.                    B       .
24.    
25.                    ENDP
26.    
27.                    ALIGN

第5行：死循環，用戶可以在此實現自己的中斷服務程序。不過很少在這里實現中斷服務程序，一般多是在其它的C文件里面重新寫一個同樣名字的中斷服務程序，因為這里是WEEK弱定義的。如果沒有在其它文件中寫中斷服務器程序，且使能了此中斷，進入到這里后，會讓程序卡在這個地方。

第14行：缺省中斷服務程序（開始）

第23行：死循環，如果用戶使能中斷服務程序，而沒有在C文件里面寫中斷服務程序的話，都會進入到這里。比如在程序里面使能了串口1中斷，而沒有寫中斷服務程序USART1_IRQHandle，那么串口中斷來了，會進入到這個死循環。

第25行：缺省中斷服務程序（結束）。

第7部分代碼分析

啟動代碼的最后一部分：

1.    ;*******************************************************************************
2.    ; User Stack and Heap initialization
3.    ;*******************************************************************************
4.                     IF      __MICROLIB
5.                    
6.                     EXPORT  __initial_sp
7.                     EXPORT  __heap_base
8.                     EXPORT  __heap_limit
9.                    
10.                     ELSE
11.                    
12.                     IMPORT  __use_two_region_memory
13.                     EXPORT  __user_initial_stackheap
14.                     
15.    __user_initial_stackheap
16.    
17.                     LDR     R0, =  Heap_Mem
18.                     LDR     R1, =(Stack_Mem + Stack_Size)
19.                     LDR     R2, = (Heap_Mem +  Heap_Size)
20.                     LDR     R3, = Stack_Mem
21.                     BX      LR
22.    
23.                     ALIGN
24.    
25.                     ENDIF
26.    
27.                     END

第4行：簡單的匯編語言實現IF…….ELSE…………語句。如果定義了MICROLIB，那么程序是不會執行ELSE分支的代碼。__MICROLIB可能大家并不陌生，就在MDK的Target Option里面設置。

第5行：__user_initial_stackheap將由__main函數進行調用。

MicroLib

MicroLib是MDK里面帶的微庫，針對嵌入式應用，MicroLIB做了深度優化，比使用C標準庫所需的RAM和FLASH空間都大大減小比如調用：

，，，

更多相關知識可以地址：http://www.keil.com/arm/microlib.asp。另外注意microlib只有庫，沒有源文件。下圖是標準庫和微庫生成代碼的比較。

4 BOOT啟動模式

相比F1，F4的啟動方式，H7的啟動方式更靈活些，只需一個boot引腳即可。但是一個引腳只能區分出兩個狀態，為了解決這個問題，H7專門配套了兩個option bytes選項字節配置，如此以來就可以方便設置各種存儲器地址了。

BOOT_ADD0和BOOT_ADD1對應32位地址到高16位，這點要特別注意。通過這兩個選項字節，所有0x0000 0000到0x3FFF 0000的存儲器地址都可以設置，包括：

所有Flash地址空間。

所有RAM地址空間，ITCM，DTCM和SRAM。

設置了選項字節后，掉電不會丟失，下次上電或者復位后，會根據BOOT引腳狀態從BOOT_ADD0，或BOOT_ADD1所設置的地址進行啟動。

使用BOOT功能，注意以下幾個問題：

如果用戶不慎，設置的地址范圍不在有效的存儲器地址，那么BOOT = 0時，會從Flash首地址0x0800 0000啟動，BOOT = 1時，會從ITCM首地址0x0000 0000啟動。

如果用戶使能了Flash Level 2保護，那么只能從Flash地址空間進行啟動。

F1,F4的啟動方式

作為對比，這里補充F1，F4的啟動方式，由BOOT0和BOOT1引腳共同決定。

5 總結

本章節講解的啟動過程分析還是比較重要的，忘初學者務必掌握。

審核編輯：湯梓紅