本應(yīng)用筆記介紹如何管理帶有頁面擦除（PE）閃存的MAXQ7665閃存微控制器（μC）中的內(nèi)部數(shù)據(jù)和程序閃存。此討論包括有關(guān)執(zhí)行程序閃存的應(yīng)用程序內(nèi)編程 （IAP） 的一般信息。

內(nèi)存映射

本節(jié)詳細(xì)介紹MAXQ7665 μC系列各種存儲器尺寸的一般閃存信息和存儲器結(jié)構(gòu)。MAX7665器件提供三種類型的閃存：扇區(qū)擦除、單字擦除和兩頁擦除。本文檔僅介紹帶PE閃存和兩頁擦除數(shù)據(jù)閃存的MAXQ7665器件;該討論不適用于僅扇區(qū)擦除設(shè)備或具有單字可擦除數(shù)據(jù)閃存的設(shè)備。

表1至表3分別顯示了從程序閃存、實用程序ROM和數(shù)據(jù)SRAM執(zhí)行代碼時16KB器件的存儲器映射。圖 1 和圖 2 顯示了 16KB 和 256B 程序閃存的扇區(qū)和頁面結(jié)構(gòu)。其他閃光燈選項可用;請參考MAXQ7665數(shù)據(jù)資料獲取完整列表。

表 1.16KB 內(nèi)存空間 — 從程序閃存執(zhí)行

表 2.16KB 內(nèi)存空間 — 從實用程序 ROM 執(zhí)行

表 3.16KB 內(nèi)存空間 — 從數(shù)據(jù) SRAM 執(zhí)行

圖1.16KB程序閃存的扇區(qū)/頁面結(jié)構(gòu)。

圖2.256B數(shù)據(jù)閃存的扇區(qū)/頁面結(jié)構(gòu)。

使用數(shù)據(jù)閃存存儲數(shù)據(jù)

閃存可用于可靠地存儲系統(tǒng)數(shù)據(jù)，這些數(shù)據(jù)需要在系統(tǒng)運行期間進(jìn)行一次或定期編程。與EEPROM不同，MAXQ7665上的PE閃存不能被字節(jié)/字擦除。必須一次擦除兩頁。這通常需要 10 毫秒，但在最壞的情況下可能需要更長的時間。在此期間，用戶代碼將停止，因此不會進(jìn)行其他處理。

有多種存儲數(shù)據(jù)到閃存的技術(shù)，在為應(yīng)用程序選擇適當(dāng)?shù)姆椒〞r，必須考慮幾個因素。應(yīng)用程序是否需要確保在新數(shù)據(jù)完全寫入之前當(dāng)前數(shù)據(jù)保持不變？如果答案是肯定的，那么某種形式的組切換技術(shù)是必要的，這樣在寫入新數(shù)據(jù)時不會丟失當(dāng)前數(shù)據(jù)。在產(chǎn)品的生命周期內(nèi)將發(fā)生多少個擦除/寫入周期？如果擦除/寫入周期數(shù)將超過數(shù)據(jù)手冊中規(guī)定的最大值，則使用綁定隊列方法可以將這些周期分散到數(shù)據(jù)閃存的多頁上，從而顯著增加總擦除/寫入周期。對于大多數(shù)周期性數(shù)據(jù)存儲需求，銀行交換和/或有界隊列技術(shù)滿足系統(tǒng)的可靠性要求和需求。以下是每種技術(shù)的簡單示例。

銀行切換

存儲體交換是在擦除/寫入周期中防止數(shù)據(jù)丟失或損壞的有效方法。此方法通過始終維護至少一個數(shù)據(jù)副本來很好地工作。組交換的缺點是它需要的數(shù)據(jù)閃存量是有界隊列方法的兩倍。事實上，銀行切換實際上只是隊列大小為 2 的有界隊列方法。因此，有關(guān)如何實現(xiàn)有界隊列的詳細(xì)信息，請參閱下一節(jié)。

有界隊列

有界隊列是受固定數(shù)量的項限制的隊列，通常在處理定期數(shù)據(jù)時使用。有界隊列是通過創(chuàng)建與所需數(shù)據(jù)塊大小相等的“條目”的固定長度隊列來形成的。條目大小特定于應(yīng)用程序，必須向上舍入到最接近的頁面擦除邊界。注意：可以擦除的最小大小為兩頁/字。雖然可以根據(jù)應(yīng)用程序要求以多種方式對數(shù)據(jù)閃存進(jìn)行分區(qū)，但由于數(shù)據(jù)閃存施加的兩頁擦除限制，條目被限制為兩頁的倍數(shù)。例如，512 x 16 數(shù)據(jù)閃存可以分為 32 個 16 字條目，這將產(chǎn)生表 4 中的內(nèi)存映射。

初始化后，啟動例程可以掃描隊列條目以確定隊列中的下一個可用條目。一旦隊列已滿，就可以使其包裝回開頭。擦除數(shù)據(jù)閃存條目后，可以寫入新條目。圖 3 說明了進(jìn)入有界隊列的條目流。

圖3.有界隊列流的圖示。

實用程序 ROM 閃存例程

為了編程、擦除和驗證閃存，MAXQ7665微控制器在ROM （只讀存儲器）中提供了片內(nèi)閃存支持程序。有兩種方法可以訪問這些例程：直接訪問和通過查找表間接訪問。最快的方法是直接訪問，即直接調(diào)用例程。為此，請?zhí)峁┌韵滦械念^文件：

u16 flashErasePage(void *);
u16 flashEraseSector(void *);
u16 flashEraseAll(void);

u16 dataFlashWrite(u16 *pAddress, u16 iData);
u16 dataFlashErasePage(void *);
u16 dataFlashEraseSector(void *);
u16 dataFlashEraseAll(void);

接下來，添加鏈接器定義以為每個例程分配適當(dāng)?shù)牡刂?。對?IAR 鏈接器文件，添加的行如下所示：

-DflashEraseSector=0x8XXX
-DflashErasePage=0x8XXX
-DflashEraseAll=0x8XXX

將 0x8XXX 替換為每個例程的相應(yīng)內(nèi)存地址。其他編譯器可能會使用不同的方法來添加這些引用。

flashWrite（） 實用程序例程不能直接從 C 調(diào)用，因為參數(shù)傳遞與 C 語言不兼容。必須編寫如下所示的小型程序集例程才能調(diào)用此函數(shù)。

注意：直接訪問方法不提供與未來 ROM 版本的向前兼容性。

第二種方法是通過表查找進(jìn)行間接訪問。此方法提供了與未來ROM版本的更大兼容性，但消耗更多的執(zhí)行時間。在下面描述的每個例程之后，程序集例程使用表查找方法來獲取 ROM 實用程序例程的地址。表 5 顯示了實用程序 ROM 提供的閃存例程。有關(guān)實用程序ROM例程的完整列表，請參考MAXQ7665用戶指南。

下面的匯編代碼示例使用間接尋址方法（查找表）調(diào)用 flashWrite（） 實用例程。此例程可由 C 代碼調(diào)用。

; This routine is callable by C code using the following prototype
; u16 flashWrite(u16 *pDest, u16 *pSrc);
;
flashWrite:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #2           ; Set ACC to A[2].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #14               ; Add the index to the flashWrite routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    push DP[1]             ; Save Frame Pointer on the stack.
    move DP[0],A[0]        ; Move argument 0(dest address) to DP[0].
    move DP[1],A[1]        ; Move argument 1(src address) to DP[1].
    call ACC               ; Execute the routine.
    pop  DP[1]             ; Restore Frame Pointer.
    ret                    ; Status returned in A[0].

; This routine is callable by C code using the following prototype
; u16 flashErasePage(void *pAddress);
;
flashErasePage:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #1           ; Set ACC to A[1].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #1                ; Add the index to the flashEraseSector routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret                    ; Status returned in A[0].

; This routine is callable by C code using the following prototype
; void flashEraseAll(void);
;
flashEraseAll:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #0           ; Set ACC to A[0].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #2                ; Add the index to the flashEraseAll routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret

下面的匯編代碼示例將 moveDP0 轉(zhuǎn)換為 C 可調(diào)用例程。如果速度對應(yīng)用程序至關(guān)重要，則應(yīng)為特定任務(wù)編寫自定義匯編語言例程。有幾個像這樣的實用程序ROM例程將有助于從閃存寫入有效的數(shù)據(jù)傳輸。

; This routine is callable by C code using the following prototype
; u16 flashRead(u16 *pAddress);
;
flashRead:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #1           ; Set ACC to A[1].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #3                ; Add the index to the moveDP0 routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    push DP[1]             ; Save Frame Pointer on the stack.
    move DP[0],A[0]        ; Move argument 0(src address) to DP[0].
    call ACC               ; Execute the routine.
    pop  DP[1]             ; Restore Frame Pointer.
    move A[0],GR
    ret                    ; Data word returned in A[0].

; This routine is callable by C code using the following prototype
; u16 flashEraseSector(void *pAddress);
;
flashEraseSector:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #1           ; Set ACC to A[1].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #15               ; Add the index to the flashEraseSector routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret                    ; Status returned in A[0].

下面的匯編代碼示例使用間接尋址方法（查找表）調(diào)用 dataFlashWrite（） 實用工具例程。此例程可由 C 代碼調(diào)用。

; This routine is callable by C code using the following prototype
; u16 dataFlashWrite(void *pAddress, u16 iData);
;
dataFlashWrite:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #2           ; Set ACC to A[2].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #16               ; Add the index to the flashWrite routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret                    ; Status returned in A[0].

; This routine is callable by C code using the following prototype
; u16 dataFlashErasePage(void *pAddress);
;
dataFlashErasePage:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #1           ; Set ACC to A[1].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #18               ; Add the index to the dataFlashErasePage routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret                    ; Status returned in A[0].

; This routine is callable by C code using the following prototype
; u16 dataFlashEraseSector(void *pAddress);
;
dataFlashEraseSector:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #1           ; Set ACC to A[1].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #19               ; Add the index to the dataFlashEraseSector routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret                    ; Status returned in A[0].

; This routine is callable by C code using the following prototype
; void dataFlashEraseAll(void);
;
dataFlashEraseAll:
    move APC, #0           ; No auto inc/dec of accumulator.
    move AP,  #0           ; Set ACC to A[0].
    move DP[0], #0800Dh    ; This is where the address of the table is stored.
    move ACC, @DP[0]       ; Get the location of the routine table.
    add  #20               ; Add the index to the flashEraseAll routine.
    move DP[0], ACC
    move ACC, @DP[0]       ; Retrieve the address of the routine.
    call ACC               ; Execute the routine.
    ret

應(yīng)用程序內(nèi)編程 （IAP）

大多數(shù)基于閃存的系統(tǒng)的一個重要要求是能夠在系統(tǒng)安裝在最終產(chǎn)品中時更新固件。此過程稱為應(yīng)用程序內(nèi)編程 （IAP）。本節(jié)將概述創(chuàng)建 IAP 應(yīng)用程序的一般準(zhǔn)則。

上一節(jié)中概述的實用程序 ROM 閃存例程執(zhí)行擦除和寫入閃存 ROM 所需的所有操作。因此，最終用戶應(yīng)用程序可以在閃存上執(zhí)行操作。與任何其他子例程調(diào)用一樣，控件將在例程完成后返回到最終用戶的代碼。

對于可靠的 IAP，引導(dǎo)加載程序應(yīng)用程序必須與主應(yīng)用程序分開。這確保了即使在發(fā)生不完整的重編程序列后，也可以重試重編程過程。

引導(dǎo)加載程序

ROM 在初始化后跳轉(zhuǎn)到尋址0x0000。因此，引導(dǎo)加載程序應(yīng)用程序的入口點必須放在0x0000處。引導(dǎo)加載程序應(yīng)用程序可以根據(jù)需要擴展到任意數(shù)量的閃存扇區(qū)/頁面，但使用的任何頁面都不適用于用戶的應(yīng)用程序代碼。表6列出了擦除和寫入閃存時必須滿足的具體要求。

圖4中的流程圖顯示了MAXQ7665退出復(fù)位狀態(tài)時的作用。在診斷ROM本身并驗證閃存已準(zhǔn)備就緒后，ROM初始化代碼將直接跳轉(zhuǎn)到地址0x0000。

圖4.簡化ROM初始化的流程圖。

圖 5 流程圖顯示了一個簡單的引導(dǎo)加載程序應(yīng)用程序如何運行。一個簡單的應(yīng)用程序標(biāo)頭可能如下所示：

typedef struct {
    u16 iSize;  // The size of the application in words
    u32 iCRC;   // The CRC of the application
    u8 ID[8];   // ID string for current application
} APPLICATION_HEADER;

使用此標(biāo)頭中的信息，引導(dǎo)加載程序可以檢查主應(yīng)用程序的有效性，并在請求時報告版本標(biāo)識。

圖5.簡化的閃存引導(dǎo)加載程序的流程圖。

編程順序本身非常簡單。通過調(diào)用 flashEraseSector（） 和/或 flashErasePage（） 擦除包含主應(yīng)用程序代碼的每個扇區(qū)/頁面。然后通過為每 32 個需要編程的單詞調(diào)用 flashWrite（） 一次寫一頁。我們建議您先擦除包含應(yīng)用程序標(biāo)題的頁面，最后對CRC數(shù)據(jù)進(jìn)行編程，以最大程度地減少CRC匹配錯誤的可能性。重新刷新通過串行端口獲取數(shù)據(jù)的微控制器的一個非常簡單的例程如下所示：

/*
// VerySimpleReFlash()
//    As simple as it gets.
//    Step 1. Wait for erase command, then erase flash.
//    Step 2. Wait for program command, program flash one word at a time.
*/
void VerySimpleReFlash()
{
u16 iStatus;             // The status returned from flash utility ROM calls
s32 iSize;               // The size of the main code to program
u16 *pAddress = 0x2000;  // The starting address of the main application
u16 i;

    InitializeCOMM();    // Can be CAN or UART.
    WaitForEraseCommand();

    // Assume that application starts at the beginning of a sector.
    for (i=C_START_SECTOR;i 0)
    {
        u16 iData[32];
        Get32WordsFromCOMM(iData);
        iStatus = flashWrite(pAddress, iData);
        if (iStatus)
            break;
        pAddress += 32;
        iSize -= 32;
        UpdateWatchdog();    // Prevent timeout
    }

    SendFlashWriteResponse(iStatus);
    ResetMicro();
}

審核編輯：郭婷