這篇文章來源于DevicePlus.com英語網站的翻譯稿。

在利用ROHM傳感器評估套件實現UCLA AirMouse – 第1部分中，我們完成了項目的硬件。對于發射器部分，我們將AirMouse按鈕以及Uno的GPIO引腳和RF模塊之間的接口組裝在一塊面包板上。由于ROHM傳感器開發板（SensorShield）在原型設計和DIY項目方面的應用非常方便，因此我們選擇將其與加速度計模塊接合在一起使用。正如您將在本教程中看到的那樣，ROHM開發板內置Arduino與其外設之間的I2C通信功能，因此，用戶通過一些簡單代碼就可以接收加速度計的數據，無需編寫任何底層I2C函數來發送和接收來自設備地址的數據。對于接收器部分，我們為Teensy微控制器組裝了類似的分線板，以便與RF模塊對接。

本教程介紹和描述的代碼將幫您將兩個模塊連接在一起，以完成該項目。我們將向您展示兩個模塊之間發送數據的基本代碼以及處理加速度計數據以在計算機顯示器上移動光標的基本代碼。同時，我們希望您能創造一些更酷的補充和改進！

AirMouse快速概覽

我們都用過電腦鼠標，但是它們只能在桌面之類的平面上工作。我們已經制作了一個“AirMouse”——一款能夠在3D空間中運行的計算機鼠標。用戶通過傾斜鼠標就可以讓屏幕上的光標移動，從而可以進行大范圍自定義動作。我們已經在第1部分中介紹了構建AirMouse的基礎知識。AirMouse主要由兩部分組成：戴在手上的鼠標發射器和連接用戶計算機的接收器。發射器收集鼠標的方向和按鈕狀態信息；而接收器則負責轉換這些信息，從而在計算機屏幕上執行相應操作。AirMouse由Arduino Uno和nRF24L01射頻模塊結合ROHM傳感器開發板的加速度計構建而成。

第1部分的硬件：

發射器：

● 1 x Arduino Uno微控制器

1 x ROHM傳感器評估套件

1 x ROHM加速度計 (KX022-1020)

1 x nRF24L01+ RF模塊

排母

滑動開關

1 x 可焊接試驗電路板，足夠大，能焊接微控制器和所有電子器件

2 x 按鍵

1 x 1s LiPo電池

1 x 1k?電阻r

1 x 3.3k?電阻

接收器：

1 x Teensy 3.2微控制器

1 x NRF24L01+ RF模塊

排母

1 x 可焊接試驗電路板，足夠大，能焊接微控制器和所有電子器件

1 x 紅、黃、綠LED燈

1 x 150?電阻

按照第1部分連接硬件之后，您就可以利用以下程序運行發送器和接收器。

發射器：

#include 
#include "RF24.h"
 
#define byte uint8_t
#include 
#include 
 
KX022 accelerometer(KX022_DEVICE_ADDRESS_1E);
 
RF24 radio(9,10);
 
uint64_t pipes[2] = {0xF0F0F0F0F0, 0xF0F1F1F1F1}; //reading, writing
 
void initRadio()
{
 radio.setPALevel(RF24_PA_HIGH);
 //payload size default 32...
 radio.setChannel(10); //you can change the channel setting
 radio.setCRCLength(RF24_CRC_16); //2-byte CRC
 radio.setDataRate(RF24_1MBPS); //1Mbps data rate
 
 radio.openReadingPipe(0, pipes[0]);
 radio.openWritingPipe(pipes[1]);
}
 
#define buttonPinR 2 //change these accordingly
#define buttonPinL 3
 
void setup() {
 // put your setup code here, to run once:
 Serial.begin(9600);
 while (!Serial);
 
 pinMode(buttonPinR, INPUT);
 pinMode(buttonPinL, INPUT);
 
 radio.begin();
 initRadio();
 radio.stopListening();
 
 Wire.begin();
 accelerometer.init();
}
 
long lastDebounceTimeR = 0;  // the last time the output pin was toggled
long lastDebounceTimeL = 0;
long debounceDelay = 50;
int buttonStateR = LOW;             // the current reading from the input pin
int buttonStateL = LOW;
int lastReadingR = LOW;
int lastReadingL = LOW;
 
char readButtonR(){
 int reading = digitalRead(buttonPinR);//get what state the button is
 char out = 'a';//the value to return if nothing special happened
 
 if (reading != lastReadingR) {//We're reading a new state for button
   // reset the debouncing timer
   lastDebounceTimeR = millis();
 }
 
 if ((millis() - lastDebounceTimeR) > debounceDelay) {//We finally have a stable value
   if (reading != buttonStateR)//Compared to our previous state, we have a flip
   {
     out = 'r';//prepare to toggle the Mini
   }
   buttonStateR = reading;//Make the buttonState the same
 }
 
 lastReadingR = reading;//make the last state the "current" state
 return out;
}
 
char readButtonL(){
 int reading = digitalRead(buttonPinL);
 char out = 'a';
 
 if (reading != lastReadingL) {
   // reset the debouncing timer
   lastDebounceTimeL = millis();
 }
 
 if ((millis() - lastDebounceTimeL) > debounceDelay) {
   
   if (reading != buttonStateL)
   {
     out = 'l';
   }
   buttonStateL = reading;
 }
 
 lastReadingL = reading;
 return out;
}
 
struct data
{
 boolean isPushedR = false;
 boolean isPushedL = false;
 int8_t acceleration[3] = {0, 0, 0};
};
 
data packet;
boolean rState = false;//these states are used to represent the current state of the buttons
boolean lState = false;
 
void loop() {    
   
   if(readButtonR() == 'r'){ //toggle button state when button state change is detected
     rState = !rState;
   }
   
   if(readButtonL() == 'l'){ //toggle button state when button state change is detected
     lState=!lState;
   }
 
   packet.isPushedR = rState;
   packet.isPushedL = lState;
 
   uint8_t rc;
   float acc[3];
   rc = accelerometer.get_val(acc);
   
   if (rc == 0)
   {
     //we cast to drop the decimal, we don't need that high precision 
     packet.acceleration[0] = (int8_t)(acc[0]*100); //x
     //Serial.print(packet.acceleration[0]); Serial.print(" ");
     packet.acceleration[1] = (int8_t)(acc[1]*100); //y
     //Serial.print(packet.acceleration[1]); Serial.print(" ");
     packet.acceleration[2] = (int8_t)(acc[2]*100); //z
     //Serial.println(packet.acceleration[2]);
   }
 
   radio.write((char*) &packet, sizeof(packet));
}

接收器：

#include 
#include "RF24.h"
 
RF24 radio(9,10);
 
uint64_t pipes[2] = {0xF0F1F1F1F1, 0xF0F0F0F0F0}; //reading, writing
 
void initRadio()
{
 radio.setPALevel(RF24_PA_HIGH);
 //payload size default 32...
 radio.setChannel(10);
 radio.setCRCLength(RF24_CRC_16); //2-byte CRC
 radio.setDataRate(RF24_1MBPS); //1Mbps data rate
 
 radio.openReadingPipe(0, pipes[0]); //reading pipe
 radio.openWritingPipe(pipes[1]);
 
 radio.startListening();
 
}
#define R_PIN 6 //Red LED
#define G_PIN 7 //Green LED
#define Y_PIN 8 //Yellow LED
 
void setup() {
 Serial.begin(9600);
 while(!Serial); //wait until Serial is initialized...(we found that not including this line of code caused errors on the 
                 //Teensy because it started executing code without ensuring that Serial communication with the laptop was
                 //properly initialized...
 radio.begin();
 initRadio();
 
 Mouse.screenSize(1920, 1080);  // configure screen size
 
 randomSeed(analogRead(0));
 
 pinMode(R_PIN, OUTPUT);
 pinMode(G_PIN, OUTPUT);
 pinMode(Y_PIN, OUTPUT);
}
 
#define CALIX 6 //calibration for X
#define CALIY -1 //calibration for Y
 
#define scalingFactor 0.05
#define THRESHOLD 1
 
double moveVector[2] = {0, 0};
 
void tiltToVector(const int8_t* acceleration){
 moveVector[0] = 0;
 moveVector[1] = 0;
 if(abs(acceleration[0] - CALIX) > THRESHOLD){ //calculate move
   moveVector[1] = (double)(acceleration[0] * scalingFactor);
 }
 if(abs(acceleration[1] - CALIY) > THRESHOLD) {
   moveVector[0] = (double)(acceleration[1] * scalingFactor);
 }
}
 
struct data
{
 boolean isPushedR = false;
 boolean isPushedL = false;
 int8_t acceleration[3] = {0, 0, 0};
};
 
data packet;
 
void loop() {
 
 bool stillWaiting = true;
 //Serial.println("About to read");
   while(stillWaiting){
     if(radio.available(0)){ //You've got mail!!!
       radio.read((char*) &packet, sizeof(packet));
       stillWaiting = false;
     }
   }
 
 Mouse.move(moveVector[0], moveVector[1]);
 Mouse.move(moveVector[0], moveVector[1]); //call it twice within the loop for smoothness :) 
 
 //prints for debugging purposes
 Serial.println("Finished writing the pins");
 if (packet.isPushedR) {
   Serial.println("The right button has been clicked!!! (Did you mean to right click?!?!)");
 }
 
 if (packet.isPushedL) {
   Serial.println("The left button has been clicked!!! (Did you mean to left click?!?!)");
   //Mouse.click();
 }
 
 Serial.print("X: ");
 Serial.println(packet.acceleration[0]);
 
 Serial.print("Y: ");
 Serial.println(packet.acceleration[1]);
 
 Serial.print("Z: ");
 Serial.println(packet.acceleration[2]);
 
 tiltToVector(packet.acceleration); //re-calculate move vector coordinates
 
 
//  Mouse.move(moveVector[0], moveVector[1]);
 
}

將代碼上傳到Teensy與將代碼上傳到Arduino Uno略有不同。對于Uno，您只需按照通常的編譯和上傳步驟執行即可:

依次選擇Tools > Board > Arduino/Genuino Uno

選擇端口（Port）

點擊Arduino IDE中的“Upload”（上傳）按鈕

而對于Teensy，請按照以下步驟上傳接收器代碼:

依次選擇Tools > Board > Teensy 3.2 / 3.1

依次選擇Tools > USB Type > Keyboard + Mouse + Joystick （我們將Teensy當作一個USB設備使用）

點擊Arduino IDE中的“Upload”（上傳）按鈕

為了本教程的目的，我們不會詳細涉及所使用的不同通信協議，也不會詳細介紹RF模塊的通信軟件。要了解有關這些主題的更多信息，請查看我們的 通信協議 和 nRF24L01+ 模塊 教程 相反，我們將簡要介紹軟件中主控制電路的工作原理。

在AirMouse中，發射器負責收集數據，但大部分數據處理由接收器模塊進行。系統的這種設計方式使得Arduino——比Teensy更弱的處理器——只需要收集數據即可，因此能夠在決策和計算上花費更少的資源，并能夠以更快的周期運行。通過這種實現方法，兩臺設備之間唯一發送的數據就是原始加速計數據和按鈕數據。Teensy接收這些原始數據并進行處理，從而在計算機屏幕上執行相應操作。

為了檢測AirMouse的方位，系統必須能夠解析原始加速計數據。要做到這一點，首先必須確定每個坐標的“零值”。零值的定義如下：AirMouse保持平坦（平行于地面）時每個軸的加速度計輸出。確定零值后，軟件就能夠將加速度計數據轉換為方向和數量，通過分析每個軸的加速度（由于重力）并將其與零值進行比較以便在屏幕上移動光標。

現在，我們來看一下接收器模塊與電腦之間的交互。Teensy被指定為USB人機界面設備（這里是指USB鼠標）。解析方位數據后，軟件會計算光標移動的速度和方向。此外，該軟件還將點擊左鍵解析為左鍵單擊，將點擊右鍵解析為右鍵單擊，調用適當的方法在計算機屏幕上顯示左鍵單擊或右鍵單擊功能。以下才是最酷的部分：您完全可以只通過軟件就能夠修改或添加鼠標的屏幕功能！目前，鼠標只具有最基本的功能和特性，但是您只需對軟件進行簡單改動，就可以輕松添加諸如滾動、將光標移至屏幕上的某個點等功能！(請點擊此處，了解Teensy USB鼠標的參考指南) 以下是您可以實現的一些很酷的硬件和軟件想法:

將不同模式的按鍵點擊用作不同的控制功能（比如，雙擊右鍵關閉窗口)

添加滾動功能！（同時點擊兩個按鍵變為“滾動模式”)

添加其他鼠標按鍵以執行滾動操作或為不同功能獲取更多按鍵模式

我們希望您能夠喜歡這個AirMouse項目，并且非常期待您可以對設計和功能進行修改和改進！

作為UCLA IEEE高級項目（Advanced Projects）計劃的一部分，最初的AirMouse由Rahul Iyer、Aaron和Andrew Wilhelm研發。

審核編輯：湯梓紅