數電基礎

時序邏輯電路會復雜很多，強烈推薦mooc上華中科技大學的數字電路與邏輯設計，是我看過講得最清楚的數電課。

前幾節都是組合邏輯電路，即輸出只與當前輸入有關，而與電路原來的狀態無關。 組合邏輯最大的缺點就是會存在 競爭冒險 ，使用時序邏輯就可以極大地避免這種問題，從而使系統更加穩定。 時序邏輯電路有記憶的功能，含有存儲電路。 其輸出是輸入及輸出前一個時刻的狀態的函數。 這里引入了現態和次態的概念，現態是當前時刻的狀態，表示為Qn，而次態表示輸入發生變化后其輸出的狀態 ，表示為Qn+1。 時序邏輯電路可以分為同步時序和異步時序，同步時序有統一的時鐘，而異步時序的觸發器狀態的變化不是同一時間發生的。

時序邏輯最基本的單元就是寄存器，寄存器具有存儲功能，一般是由D觸發器構成，由時鐘脈沖控制，每個D觸發器（DFF）能夠存儲一位二進制碼。

D觸發器

D觸發器是一種最簡單的觸發器。 D觸發器的特點是：在時鐘上升沿時，次態=輸入D，在時鐘處于高電平或低電平時，次態保持不變。 用表格表示：

同步復位的D觸發器

當時鐘的上升沿到來時，檢測到按鍵的復位操作才有效，否則無效。 clk是時鐘，rst_n是復位鍵（低電平有效），在前兩條虛線中，key_in在時鐘上升沿變為1，但是led_out不能立刻改變，而是在下一個時鐘上升沿時變為key_in（Qn+=D)。 key_in的抖動也不會影響到led_out。 注意 ：第五條虛線，sys_rst_n被拉低后led_out沒有立刻復位變為0，而是當syc_clk的上升沿到來的時候（第六條虛線）led_out才復位成功，在復位釋放的時候也是相同原因（第七條虛線）。

同步復位的D觸發器

異步的意思是和工作時鐘不同步，只要有檢測到按鍵被按下，就立刻執行復位操作。 第五條虛線，sys_rst_n被拉低后led_out立刻變為0，沒有等時鐘上升沿，復位釋放時需要等待時鐘上升沿才會為key_in。

同步和異步復位的D觸發器區別只在于復位時需不需要等時鐘上升沿。 他們的共同點是對于電路中產生的毛刺有著極好的屏蔽作用。

設計規劃

本例中我們的目標和（一）中一樣，點亮一個LED燈。 但是這里使用的D觸發器，當按鍵被按下，key_in=0作為輸入給觸發器的D端口，然后在時鐘上升沿時會被傳送給輸出led_out=0使LED燈被點亮。

編寫代碼

同步復位的代碼

module flip_flop
(
input wire sys_clk , //系統時鐘50Mh


input wire sys_rst_n, //全局復位


 input wire key_in , 


 output reg led_out 
 );
 always@(posedge sys_clk) 
 if(sys_rst_n == 1'b0) 
 led_out <= 1'b0; 
 else
 led_out <= key_in;
 endmodule

同步復位的特點是，復位時要等待上升沿，因此需要在上升沿時檢測復位狀態，這樣就能保證復位信號在上升沿時才有效。 使用always語句，時鐘上升沿時執行塊中的判斷語句，當復位信號為低電平時，LED燈點亮，否則，將key_in賦給led_out。 （四）中提到**always 時序邏輯塊中多用非阻塞賦值<=。 **

異步復位的代碼

module flip_flop
(
input wire sys_clk , //系統時鐘50Mh
input wire sys_rst_n , //全局復位
input wire key_in , 
output reg led_out 
);


 always@(posedge sys_clk or negedge sys_rst_n)
 if(sys_rst_n == 1'b0)//sys_rst_n為低電平時復位，且是檢測到sys_rst_n的下
 //降沿時立刻復位，不需等待sys_clk的上升沿來到后再復位
 led_out <= 1'b0;
 else
 led_out <= key_in;


 endmodule

異步復位的特點是，復位時不需要等待上升沿。 當電路發生always語句()中的變化時，執行always塊，由于復位不需要等待上升沿，這里發生變化的條件就包含時鐘上升和復位有效。 當時鐘上升或復位有效時，執行判斷語句，如果復位鍵為低電平則LED輸出低電平點亮，否則將key_in的值賦給led_out。

我們采用同步復位來演示。 將代碼綜合看RTL視圖

如果復位鍵為低電平，那么復位有效，0被傳給觸發器并輸出，如果復位鍵為高電平，那么key_in的值被傳給觸發器并輸出，與我們的設計含義一致。

編寫testbench

`timescale 1ns/1ns
module tb_flip_flop();
reg sys_clk ;
reg sys_rst_n ;
reg key_in ;
wire led_out ;


 //初始化系統時鐘、全局復位和輸入信號
 initial begin
 sys_clk = 1'b1; 
 sys_rst_n <= 1'b0; 
 key_in <= 1'b0; 
 #20
 sys_rst_n <= 1'b1; //初始化20ns后，復位釋放
 #210
 sys_rst_n <= 1'b0; //為了觀察同步復位和異步復位的區別
 sys_rst_n <= 1'b1; //復位40ns后再次讓復位釋放掉
 end


 //sys_clk:模擬系統時鐘，每10ns電平翻轉一次，周期為20ns，頻率為50MHz
 always #10 sys_clk = ~sys_clk; 
 always #20 key_in <= {$random} % 2; 


 //------------------------------------------------------------
 initial begin
 $timeformat(-9, 0, "ns", 6);
 $monitor("@time %t: key_in=%b led_out=%b", $time, key_in, led_out);
 end
 //------------------------------------------------------------


 //------------------flip_flop_inst-------------------
 flip_flop flip_flop_inst
 (
 .sys_clk (sys_clk ), //input sys_clk
 .sys_rst_n (sys_rst_n ), //input sys_rst_n
 .key_in (key_in ), //input key_in
 .led_out (led_out ) //output led_out
 );


 endmodule

初始化：initial 塊中時鐘信號用阻塞賦值=，其他信號用非阻塞賦值。 初始時時鐘為高電平，復位為低電平，key_in無所謂，此時輸出不能確定。 延時20ns后復位釋放，再延時210ns后再次復位， 這么做的目的是：由于時鐘周期是20ns（后面的代碼可以看出來），在時鐘下降沿復位可以觀察同步復位和異步復位的變化。 同步復位要等時鐘上升沿才變化，異步復位是即刻復位。 再延時40ns后再次復位釋放。

模擬時鐘：每隔10ns翻轉一次，周期為20ns。 模擬按鍵輸入：每隔20ns產生一個0或1的隨機數。 時間間隔應該小于等于時鐘周期，否則會產生毛刺。

打印和實例化與之前的沒有區別。

對比波形

同步復位電路：最開始的輸出不確定，20ns-210ns間，Qn+1=D，發現輸出與上一時刻的輸入相同，這是D觸發器的特征，210ns時復位有效，但是同步復位要等下一個時鐘上升沿，輸出才會為0。 250ns復位釋放，等到時鐘上升沿260ns之后，輸出才變為上一時刻的輸入。

觀察一下異步復位

分配管腳

不同開發板的管腳設置不同，需要看用戶手冊的介紹。 這里時鐘周期是20ns，也就是50MHz的時鐘晶振，選擇E1管腳。

全編譯后上板驗證

用的異步復位，S0為key_in，S1為復位，LED0是輸出。 當key_in不按時為高電平，燈也為高電平熄滅，當復位鍵按下時，即刻復位燈亮。 當key_in按下去時為低電平燈亮。