理論學習

我們知道除了只讀存儲器外還有隨機存取存儲器，這一篇將介紹另一種 存儲類IP核 ——RAM的使用方法。RAM是 隨機存取存儲器 （Random Access Memory），是一個易失性存儲器，斷電丟失。RAM工作時可以隨時從任何一個指定的地址寫入或讀出數據。

同樣的，Altera推出的RAM IP核分為兩種類型：單端口RAM和雙端口RAM。其中雙端口RAM又分為簡單雙端口RAM（Simple dual port RAM）和真正雙端口RAM（True dual port RAM）。對于單端口RAM，讀寫操作共用一組地址線，讀寫操作不能同時進行；對于簡單雙端口RAM，讀操作和寫操作有專用地址端口（一個讀端口和一個寫端口），即寫端口只能寫不能讀，而讀 端口只能讀不能寫；對于真正雙端口RAM，有兩個地址端口用于讀寫操作（兩個讀/寫端口），即兩個端口都可以進行讀寫。

RAM IP核配置

一端口的配置幾乎和rom沒有區別

勾選上創建“aclr”異步復位信號以及是否創建“rden”讀使能信號

簡單雙端口和真正雙端口都是在雙端口中去配置的，配置的選項的定義和ROM中一樣

真正雙端口的配置除了選擇真正雙端口以外，其他的選項和簡單雙端口的配置一樣

設計規劃

按下按鍵1時往RAM地址0255里寫入數據0255；按下按鍵2時讀取RAM內的數據，從地址0開始每隔0.2s地址加1往下進行讀取；再次按下按鍵1時停止讀取重新寫入數據0~255；再次按下按鍵2時從頭開始讀取數據

一共有5個模塊：按鍵消抖模塊（使用兩次），RAM控制模塊，IP核，數碼管動態顯示模塊，頂層模塊。實際需要做的是RAM控制模塊

編寫代碼

ROM控制模塊

RAM的寫時序為：當RAM寫時鐘上升沿采到寫使能為高時，就能將該上升沿采到的數據寫入該上升沿采到的地址中。

RAM的讀時序為：當RAM讀時鐘上升沿采到讀使能為高時，就能讀出該上升沿采到的地址中的數據。若是我們配置IP核時 沒有生成RAM讀使能 ，那么RAM就能直接讀出讀時鐘上升沿采到的地址中的數據。

按鍵1按下key_flag1拉高一個時鐘，寫使能有效，地址從0-255，寫數據從0-255，寫完后寫使能釋放；按鍵2按下時key_flag2拉高一個時鐘，讀使能有效，cnt_200開始計數，每0.2s讀取一次給出地址對應的數據。讀完255后回到0繼續讀取，如此循環，直至再次按下按鍵1，則讀使能釋放，再次寫入數據。

若寫使能有效時，按下按鍵2并不能讀數據。寫使能有效時再次按下按鍵1，地址歸0重新寫入。

module ram_ctrl
(
input wire sys_clk , 
input wire sys_rst_n , 
input wire key1_flag , 
input wire key2_flag , 
output reg wr_en , //寫RAM使能，高電平有效
output reg rd_en , //讀RAM使能，高電平有效
 output reg [7:0] addr , //讀寫RAM地址
 output wire [7:0] wr_data //寫RAM數據
 );


 //parameter define
 parameter CNT_MAX = 9_999_999; //0.2s計數器最大值


 //reg define
 reg [23:0] cnt_200ms ; //0.2s計數器


 //讓寫入的數據等于地址數，即寫入數據0~255
 assign wr_data = (wr_en == 1'b1) ? addr : 8'd0;


 //wr_en:產生寫RAM使能信號
 always@(posedge sys_clk or negedge sys_rst_n)
 if(sys_rst_n == 1'b0)
 wr_en <= 1'b0;
 else if(addr == 8'd255)
 wr_en <= 1'b0;
 else if(key1_flag == 1'b1)
 wr_en <= 1'b1;


 //rd_en:產生讀RAM使能信號
 always@(posedge sys_clk or negedge sys_rst_n)
 if(sys_rst_n == 1'b0)
 rd_en <= 1'b0;
 else if(key2_flag == 1'b1 && wr_en == 1'b0)
 rd_en <= 1'b1;
 else if(key1_flag == 1'b1)
 rd_en <= 1'b0;
 else
 rd_en <= rd_en;


 //0.2s循環計數
 always@(posedge sys_clk or negedge sys_rst_n)
 if(sys_rst_n == 1'b0)
 cnt_200ms <= 24'd0;
 else if(cnt_200ms == CNT_MAX || key2_flag == 1'b1)
 cnt_200ms <= 24'd0;
 else if(rd_en == 1'b1)
 cnt_200ms <= cnt_200ms + 1'b1;


 //寫使能有效時，
 always@(posedge sys_clk or negedge sys_rst_n)
 if(sys_rst_n == 1'b0)
 addr <= 8'd0;
 else if((addr == 8'd255 && cnt_200ms == CNT_MAX) ||
 (addr == 8'd255 && wr_en == 1'b1) ||
 (key2_flag == 1'b1) || (key1_flag == 1'b1))
 addr <= 8'd0;
 else if((wr_en == 1'b1) || (rd_en == 1'b1 && cnt_200ms == CNT_MAX))
 addr <= addr + 1'b1;


 endmodule

輸入信號有時鐘，復位，按鍵1標志信號，按鍵2標志信號，輸出信號有寫使能，讀使能，讀寫地址，寫數據

參數定義：計數器的最大計數值是9_999_999

寫入數據和地址一致，用三目運算符進行選擇，如果寫使能有效，寫數據就是地址，無效寫數據就為0

寫使能信號：復位有效時寫使能歸0；地址為255時寫使能歸0；按鍵1標志信號拉高時寫使能拉高

讀使能信號：復位有效時讀使能歸0；按鍵1標志信號拉高時讀使能歸0（即使在讀數據，寫使能有效時優先寫入數據）；按鍵2標志信號拉高且寫使能無效時，讀信號拉高（寫數據優先，寫使能無效時才能讀數據）；其他情況讀使能保持

計數cnt_200ms：復位有效時計數器歸0；計數到最大值且按鍵2標志信號拉高時計數器歸0；讀使能有效時計數器+1

地址信號：復位有效時地址歸0；地址為255且計數到最大值或者地址為255且寫使能有效或者按鍵2標志信號拉高或者按鍵1標志信號拉高時地址歸0；寫使能有效或讀使能為1且計數到最大值時地址+1

**頂層模塊
**

module ram
(
input wire sys_clk , 
input wire sys_rst_n , 
input wire [1:0] key ,
output wire stcp , 
output wire shcp , 
output wire ds 
 );


 //wire define
 wire wr_en ; 
 wire rd_en ; 
 wire [7:0] addr ; 
 wire [7:0] wr_data ; 
 wire [7:0] rd_data ; 
 wire key1_flag ; 
 wire key2_flag ; 


 ram_ctrl ram_ctrl_inst
 (
 .sys_clk (sys_clk ), 
 .sys_rst_n (sys_rst_n ), 
 .key1_flag (key1_flag ), 
 .key2_flag (key2_flag ), 
 .wr_en (wr_en ), 
 .rd_en (rd_en ), 
 .addr (addr ), 
 .wr_data (wr_data ) 
 );


 key_filter key1_filter_inst
 (
 .sys_clk (sys_clk ), 
 .sys_rst_n (sys_rst_n ), 
 .key_in (key[0] ), 
 .key_flag (key1_flag ) 
 );


 key_filter key2_filter_inst
 (
 .sys_clk (sys_clk ), 
 .sys_rst_n (sys_rst_n ), 
 .key_in (key[1] ), 
 .key_flag (key2_flag ) 
 );


 seg_595_dynamic seg_595_dynamic_inst
 (
 .sys_clk (sys_clk ), 
 .sys_rst_n (sys_rst_n ), 
 .data ({12'd0,rd_data} ), 
 .seg_en (1'b1 ), //數碼管使能信號，高電平有效
 .stcp (stcp ), //輸出數據存儲寄時鐘
 .shcp (shcp ), //移位寄存器的時鐘輸入
 .ds (ds ), //串行數據輸入
 );


 //---------------rom_256x8_inst--------------
 ram_256x8 ram_256x8_inst
 (
 .aclr (~sys_rst_n ), //異步清零信號
 .address (addr ), //讀寫地址線
 .clock (sys_clk ), //使用系統時鐘作為讀寫時鐘
 .data (wr_data ), //輸入寫入RAM的數據
 .rden (rd_en ), //讀RAM使能
 .wren (wr_en ), //寫RAM使能
 .q (rd_data ) //輸出讀RAM數據
 );
 endmodule

實際上是幾個模塊的實例化：ram控制模塊，按鍵消抖模塊要實例化兩次，第一個模塊的key_in對應著key[0]，flag對應key1_flag，第二個模塊的key_in對應著key[1]，flag對應key2_flag，數碼管動態顯示模塊將使能信號置1，ram的ip核模塊的異步清零信號置為復位信號取反，其他信號名和控制模塊中定義的信號名對接

Testbench

`timescale 1ns/1ns
module tb_ram();


//wire define
wire stcp;
wire shcp;
wire ds ;
//reg define
reg sys_clk ;
reg sys_rst_n ;
reg [1:0] key ;


//對sys_clk,sys_rst賦初值，并模擬按鍵抖動
initial
begin
sys_clk = 1'b1 ;
sys_rst_n <= 1'b0 ;
key <= 2'b11;
#200 sys_rst_n <= 1'b1 ;
//按下按鍵key[1]
#2000 key[1] <= 1'b0;//按下按鍵
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#200 key[1] <= 1'b1;//松開按鍵
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
//按下按鍵key[0]
#2000 key[0] <= 1'b0;//按下按鍵
#20 key[0] <= 1'b1;//模擬抖動
#20 key[0] <= 1'b0;//模擬抖動
#20 key[0] <= 1'b1;//模擬抖動
#20 key[0] <= 1'b0;//模擬抖動
#200 key[0] <= 1'b1;//松開按鍵
#20 key[0] <= 1'b0;//模擬抖動
#20 key[0] <= 1'b1;//模擬抖動
#20 key[0] <= 1'b0;//模擬抖動
#20 key[0] <= 1'b1;//模擬抖動
//按下按鍵key[1]
#2000 key[1] <= 1'b0;//按下按鍵
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#200 key[1] <= 1'b1;//松開按鍵
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
//按下按鍵key[1]
#2000 key[1] <= 1'b0;//按下按鍵
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#200 key[1] <= 1'b1;//松開按鍵
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
//按下按鍵key[0]
#2000 key[0] <= 1'b0;//按下按鍵
#20 key[0] <= 1'b1;//模擬抖動
#20 key[0] <= 1'b0;//模擬抖動
#20 key[0] <= 1'b1;//模擬抖動
#20 key[0] <= 1'b0;//模擬抖動
#200 key[0] <= 1'b1;//松開按鍵
#20 key[0] <= 1'b0;//模擬抖動
#20 key[0] <= 1'b1;//模擬抖動
#20 key[0] <= 1'b0;//模擬抖動
#20 key[0] <= 1'b1;//模擬抖動
//按下按鍵key[1]
#2000 key[1] <= 1'b0;//按下按鍵
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#200 key[1] <= 1'b1;//松開按鍵
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
#20 key[1] <= 1'b0;//模擬抖動
#20 key[1] <= 1'b1;//模擬抖動
end
//sys_clk:模擬系統時鐘，每10ns電平取反一次，周期為20ns，頻率為50MHz
always #10 sys_clk = ~sys_clk;


 //重新定義參數值，縮短仿真時間仿真
 defparam ram_inst.key1_filter_inst.CNT_MAX = 5 ;
 defparam ram_inst.key2_filter_inst.CNT_MAX = 5 ;
 defparam ram_inst.ram_ctrl_inst.CNT_MAX = 99;


 //---------------ram_inst--------------
 ram ram_inst
 (
 .sys_clk (sys_clk ), //系統時鐘，頻率50MHz
 .sys_rst_n (sys_rst_n ), //復位信號，低電平有效
 .key (key ), //輸入按鍵信號
 .stcp (stcp ), //輸出數據存儲寄時鐘
 .shcp (shcp ), //移位寄存器的時鐘輸入
 .ds (ds ), //串行數據輸入
 );
 endmodule

初始化：時鐘為高電平，復位為低電平，按鍵都為高電平表示未按下

延遲200ns后復位釋放

延遲2000ns后按下按鍵2但是模擬抖動，抖動中有200ns的按鍵是按下狀態以便識別并拉高flag

再重復模擬按下按鍵1，2，2，1，2

重新定義參數，縮短仿真時間

ram模塊實例化

波形變化

需要注意的是地址和數據需要用unsigned格式，如果用十進制會出現負數

先按下的是key2，因為還沒寫入所以讀出的q暫時沒有數據

按下按鍵1，寫使能拉高，地址和數據都開始+1，且因為正在寫數據，讀出的q暫時沒有數據

地址線和數據255后歸0保持0且寫使能拉低

寫數據后再讀數據就能讀出數據

管腳分配

和上一篇一樣

全編譯后上板驗證