描述

介紹

ThingsBoard 是一個開源服務器端平臺，可讓您監視和控制物聯網設備。它對個人和商業用途都是免費的，您可以在任何地方部署它。如果這是您第一次使用該平臺，我們建議您查看什么是事物板頁面和入門指南。

此示例應用程序將允許您使用您的 magicbit 設備和 ThingsBoard Web UI 顯示來自 DHT11 傳感器的濕度/溫度數據。

在 Magicbit 設備上運行的應用程序是使用 ThingsBoard Arduino SDK 編寫的，非常簡單易懂。

完成此示例/教程后，您將在以下儀表板上看到您的傳感器數據。

?

訪問 Thingsboard Demo 官方頁面并注冊。

在左側欄上登錄后，您將看到設備。單擊設備并添加新設備。

?

在憑據選項卡上勾選添加憑據選項卡，然后從下拉框中選擇訪問令牌。您可以添加自己的訪問令牌或留空以自動生成令牌。

在別名中將設備設置為magicbit。轉到儀表板選項卡并導入儀表板。

按照圖像中的以下步驟 導入儀表板。 在附件中找到名為“magicbit_temperature_humidity_demo_dashboard.json”的演示 JSON 文件。

?

?

?

?

按如下方式將您的魔法位與 DHT11 模塊連接到引腳 33。

?

在 Arduino IDE 中下載以下庫，

?

?

以下是您將使用的 Arduino 代碼。

注意您需要在草圖中編輯以下常量和變量：

• WIFI_AP- 您的接入點名稱
• WIFI_PASSWORD- 接入點密碼
• TOKEN- ThingsBoard 配置步驟中的$ACCESS_TOKEN 。
• THINGSBOARD_SERVER- 可在您的 wifi 網絡中訪問的 ThingsBoard 主機/IP 地址。指定demo.thingsboard.io您是否使用實時演示服務器。

#include            // DHT for Library library
#include            // WiFi control for ESP32
#include     // ThingsBoard SDK

#define DHTPIN 33     // what digital pin we're connected to

#define DHTTYPE DHT11   // DHT 11
DHT dht(DHTPIN, DHTTYPE);

// Helper macro to calculate array size
#define COUNT_OF(x) ((sizeof(x)/sizeof(0[x])) / ((size_t)(!(sizeof(x) % sizeof(0[x])))))

// WiFi access point
#define WIFI_AP_NAME       "4G"// "WIFI_AP"
// WiFi password
#define WIFI_PASSWORD      "nevergiveup"// "WIFI_PASSWORD"

// See https://thingsboard.io/docs/getting-started-guides/helloworld/
// to understand how to obtain an access token
#define TOKEN              "XZjQ26r9XJcsNkWGuASY" // "TOKEN"
// ThingsBoard server instance.
#define THINGSBOARD_SERVER  "demo.thingsboard.io"

// Baud rate for debug serial
#define SERIAL_DEBUG_BAUD    115200

// Initialize ThingsBoard client
WiFiClient espClient;
// Initialize ThingsBoard instance
ThingsBoard tb(espClient);
// the Wifi radio's status
int status = WL_IDLE_STATUS;


// Period of sending a temperature/humidity data.
int send_delay = 2000;
unsigned long millis_counter;
void InitWiFi()
{
  Serial.println("Connecting to AP ...");
  // attempt to connect to WiFi network

  WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected to AP");
}

void reconnect() {
  // Loop until we're reconnected
  status = WiFi.status();
  if ( status != WL_CONNECTED) {
    WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
    Serial.println("Connected to AP");
  }
}

// Setup an application
void setup() {
  // Initialize serial for debugging
  Serial.begin(SERIAL_DEBUG_BAUD);
  WiFi.begin(WIFI_AP_NAME, WIFI_PASSWORD);
  InitWiFi();


  // Initialize temperature sensor
  dht.begin();
}

// Main application loop
void loop() {


  // Reconnect to WiFi, if needed
  if (WiFi.status() != WL_CONNECTED) {
    reconnect();
    return;
  }


  // Reconnect to ThingsBoard, if needed
  if (!tb.connected()) {
    // Connect to the ThingsBoard
    Serial.print("Connecting to: ");
    Serial.print(THINGSBOARD_SERVER);
    Serial.print(" with token ");
    Serial.println(TOKEN);
    if (!tb.connect(THINGSBOARD_SERVER, TOKEN)) {
      Serial.println("Failed to connect");
      return;
    }
  }

 

  // Check if it is a time to send DHT11 temperature and humidity
  if(millis()-millis_counter > send_delay) {
    Serial.println("Sending data...");

    // Uploads new telemetry to ThingsBoard using MQTT.
    // See https://thingsboard.io/docs/reference/mqtt-api/#telemetry-upload-api
    // for more details
    float h = dht.readHumidity();
    // Read temperature as Celsius (the default)
    float t = dht.readTemperature();
    
    if (isnan(h) || isnan(t)) {
      Serial.println("Failed to read from DHT sensor!");
    } else {
      Serial.print("Temperature:");
      Serial.print(t);
      Serial.print(" Humidity ");
      Serial.println(h);
      tb.sendTelemetryFloat("temperature", t);
      tb.sendTelemetryFloat("humidity", h);
    }

    millis_counter = millis(); //reset millis counter
  }

  // Process messages
  tb.loop();
}

數據可視化

在現場演示服務器中：

• 登錄：您的現場演示用戶名（電子郵件）
• 密碼：您的現場演示密碼

有關如何獲取帳戶的更多詳細信息，請參閱實時演示頁面。

轉到“設備”部分并找到“Magicbit” ，打開設備詳細信息并切換到“最新遙測”選項卡。如果一切配置正確，您應該能夠看到“溫度”和“濕度”的最新值。

?

之后，打開“儀表板”部分，然后找到并打開“magicbit_temperature_humidity_demo_dashboard” 。結果，您將看到一個顯示溫度和濕度水平的時間序列圖表（類似于介紹中的儀表板圖像）。