通常，當(dāng)您使用加速度計(jì)四處移動時，它會經(jīng)歷運(yùn)動加速度。額外的加速度值可能會影響定向精度。另一個與加速度計(jì)相關(guān)的問題是噪聲：電信號中不需要的干擾。加速度計(jì)能夠測量任何角度，但是它的讀數(shù)有噪聲并且即使使用低通濾波器也有一定的誤差范圍。

另一方面，陀螺儀存在偏置不穩(wěn)定性，其中陀螺儀的初始零讀數(shù)會由于設(shè)備內(nèi)固有缺陷和噪聲的集成而導(dǎo)致隨時間漂移。

在需要通過傳感器融合進(jìn)行絕對定位的應(yīng)用中，磁力計(jì)對于校正陀螺儀漂移是絕對必要的。磁力計(jì)問題是它們的非理想響應(yīng)面和位置依賴性。

獲取實(shí)時位置

有不同的算法來解決錯誤和噪聲問題。我們將使用四元數(shù)。四元數(shù)用于純數(shù)學(xué)，但在應(yīng)用數(shù)學(xué)中也有實(shí)際用途，特別是涉及三維旋轉(zhuǎn)的計(jì)算。它們可以與其他旋轉(zhuǎn)方法一起使用，例如歐拉角和旋轉(zhuǎn)矩陣，或者作為它們的替代方法，具體取決于應(yīng)用程序。MPU9250 庫的使用使我們擺脫了對四元數(shù)所有復(fù)雜性的理解，并且實(shí)現(xiàn)已經(jīng)完成。

磁偏角

應(yīng)根據(jù)您要獲得準(zhǔn)確數(shù)據(jù)的位置來設(shè)置磁偏角。您可以在此處找到您所在城市的磁偏角。

?

請注意，此處的偏角目前為 1? 38'。提供的格式需要轉(zhuǎn)換為代碼的十進(jìn)制度數(shù)。每度有60分鐘，其中38分鐘為度的38/60，即0.63。1? 38' 的十進(jìn)制格式的赤緯為 1.63。使用您所在位置的偏角更新代碼MAGNETIC_DECLINATION常量。

磁性校準(zhǔn)

有一種簡單的方法可以自動校準(zhǔn)并糾正磁力計(jì)數(shù)據(jù)的一些錯誤。以八字形模式緩慢移動傳感器，并跟蹤在六個主要方向中的每一個方向上測量的最小和最大場。可以從后續(xù)數(shù)據(jù)中減去平均值，這相當(dāng)于將響應(yīng)曲面重新置于原點(diǎn)的中心。該庫具有自動為我們執(zhí)行的校準(zhǔn)功能，我們只需要在校準(zhǔn)開始時將傳感器移動成 8 字形即可。

為 MPU9250 安裝 Arduino 庫

要與 MPU9250 模塊交互，我們可以使用原始實(shí)現(xiàn)或利用現(xiàn)有庫。該庫提供了一個與模塊通信的接口，為我們節(jié)省了大量時間。另一個優(yōu)勢是多年來由社區(qū)測試和改進(jìn)的健壯代碼庫。我們建議使用該庫并避免從頭開始實(shí)施所有內(nèi)容。它可以從我們的官方存儲庫下載。

要導(dǎo)入庫，請打開 Arduino IDE，轉(zhuǎn)到 Sketch > Include Library > Add.ZIP Library 并選擇從我們的 GitHub 存儲庫下載的庫文件。

將外部庫包含到 Arduino IDE

?

然后你可以簡單地使用include語句：

#include "MPU9250.h"

它將包括具有預(yù)定義函數(shù)的庫，以與 MPU9250 交互。

Arduino代碼

下面的代碼很簡單，因?yàn)槲覀兪褂昧艘粋€庫，該庫提供了與 MPU9250 模塊交互的清晰接口。在設(shè)置函數(shù)中，我們配置和校準(zhǔn)模塊并在循環(huán)中每隔INTERVAL_MS_PRINT毫秒打印一次輸出。

#include "MPU9250.h"

#define MPU9250_IMU_ADDRESS 0x68

#define MAGNETIC_DECLINATION 1.63 // To be defined by user
#define INTERVAL_MS_PRINT 1000

MPU9250 mpu;

unsigned long lastPrintMillis = 0;

void setup()
{
  Serial.begin(115200);
  Wire.begin();

  Serial.println("Starting...");

  MPU9250Setting setting;

  // Sample rate must be at least 2x DLPF rate
  setting.accel_fs_sel = ACCEL_FS_SEL::A16G;
  setting.gyro_fs_sel = GYRO_FS_SEL::G1000DPS;
  setting.mag_output_bits = MAG_OUTPUT_BITS::M16BITS;
  setting.fifo_sample_rate = FIFO_SAMPLE_RATE::SMPL_250HZ;
  setting.gyro_fchoice = 0x03;
  setting.gyro_dlpf_cfg = GYRO_DLPF_CFG::DLPF_20HZ;
  setting.accel_fchoice = 0x01;
  setting.accel_dlpf_cfg = ACCEL_DLPF_CFG::DLPF_45HZ;

  mpu.setup(MPU9250_IMU_ADDRESS, setting);

  mpu.setMagneticDeclination(MAGNETIC_DECLINATION);
  mpu.selectFilter(QuatFilterSel::MADGWICK);
  mpu.setFilterIterations(15);

  Serial.println("Calibration will start in 5sec.");
  Serial.println("Please leave the device still on the flat plane.");
  delay(5000);

  Serial.println("Calibrating...");
  mpu.calibrateAccelGyro();

  Serial.println("Magnetometer calibration will start in 5sec.");
  Serial.println("Please Wave device in a figure eight until done.");
  delay(5000);

  Serial.println("Calibrating...");
  mpu.calibrateMag();

  Serial.println("Ready!");
}

void loop()
{
  unsigned long currentMillis = millis();

  if (mpu.update() && currentMillis - lastPrintMillis > INTERVAL_MS_PRINT) {
    Serial.print("TEMP:\t");
    Serial.print(mpu.getTemperature(), 2);
    Serial.print("\xC2\xB0"); //Print degree symbol
    Serial.print("C");
    Serial.println();

    Serial.print("Pitch:\t");
    Serial.print(mpu.getPitch());
    Serial.print("\xC2\xB0"); //Print degree symbol
    Serial.println();

    Serial.print("Roll:\t");
    Serial.print(mpu.getRoll());
    Serial.print("\xC2\xB0"); //Print degree symbol
    Serial.println();

    Serial.print("Yaw:\t");
    Serial.print(mpu.getYaw());
    Serial.print("\xC2\xB0"); //Print degree symbol
    Serial.println();

    Serial.println();

    lastPrintMillis = currentMillis;
  }
}

測試

串行監(jiān)視器將每INTERVAL_MS_PRINT毫秒打印一次最后可用的傳感器數(shù)據(jù)（在上面的示例中，每秒一次），它應(yīng)該類似于：

測試輸出

?

通常方向繪制在物理模塊上，因此您可以輕松檢測俯仰和滾動。

?